Contenido
Índice 🔎︎

# Funciones de hoja de cálculo

Esta sección contiene descripciones de las funciones para hojas de cálculo junto con un ejemplo.

Para acceder a esta orden…

Insertar ▸ Función ▸ categoríaHoja de cálculo

## ERROR.TYPE

Devuelve un número que representa un tipo específico de error o el valor de error #N/D si no hay error.

## AREAS

Devuelve el número de áreas individuales que pertenecen a un área múltiple. Un área se puede componer de celdas adyacentes o de una única celda.

La función espera un único argumento. Si define varios intervalos, debe incluirlos entre paréntesis adicionales. Se pueden especificar varios intervalos mediante un punto y coma (;), pero este se convertirá automáticamente en el operador virgulilla (~). La virgulilla se utiliza para unir intervalos.

#### Sintaxis

AREAS(Referencia)

La referencia es la referencia a una celda o a un área de celdas.

#### Ejemplo

=AREAS((A1:B3;F2;G1)) devuelve 3, ya que es una referencia a tres celdas y/o áreas. Tras la entrada se convierte en =AREAS((A1:B3~F2~G1)).

=AREAS(Todas) devuelve 1 si ha definido un área llamada «Todas» en Datos ▸ Definir intervalo.

## BUSCAR

Devuelve el contenido de una celda proveniente bien de un intervalo de una sola columna o bien de uno de una sola fila. Facultativamente, el valor asignado (del mismo índice) se puede devolver en una columna o una fila distinta. A diferencia de BUSCARV y BUSCARH, el vector de búsqueda y de resultados puede situarse en posiciones desiguales; no tienen que ser adyacentes. Asimismo, el vector de búsquedas de BUSCAR ha de ordenarse ascendentemente, o de lo contrario la búsqueda no producirá resultados aprovechables.

Si BUSCAR no puede encontrar el criterio de búsqueda, utiliza el valor más grande del vector de búsqueda que sea menor que o igual al criterio de búsqueda.

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Sintaxis

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

VectordeBúsqueda es el área de una columna o una fila que se va a buscar.

VectordeResultado es otra área de una columna o una fila desde la que se toma el resultado de la función. El resultado es la celda del vector de resultado con el mismo índice que la instancia que se encontró con el vector de búsqueda.

Tratamiento de celdas vacías

#### Ejemplo

=BUSCAR(A1;D1:D100;F1:F100) busca la celda correspondiente en el área D1:D100 del número especificado en A1. Para la instancia encontrada, se determina el índice, por ejemplo, la celda 12 de esta área. A continuación, el contenido de la celda 12 se devuelve como el valor de la función (en el vector de resultado).

## BUSCARH

Busca un valor y una referencia a las celdas situadas por debajo del área seleccionada. Esta función comprueba si la primera fila de una matriz contiene un cierto valor. La función devuelve el valor situado en una fila de la matriz, indicada en Índice, en la misma columna.

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Sintaxis

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Para una explicación de los parámetros, vea: BUSCARV (donde se lee filas, lea columnas y viceversa)

Tratamiento de celdas vacías

#### Ejemplo

Se tiene una pequeña tabla de base de datos en el intervalo de celdas A1:DO4, que contiene información básica sobre 118 elementos químicos. La primera columna contiene los títulos de las filas «Elemento», «Símbolo», «Número atómico» y «Masa atómica relativa». Las columnas subsecuentes contienen la información relativa a cada uno de los elementos, ordenada de izquierda a derecha por número atómico. Por ejemplo, las celdas B1:B4 contienen «Hidrógeno», «H», «1» y «1,008», en tanto que las celdas DO1:DO4 contienen «Oganesón», «Og», «118» y «294».

| A | B | C | D | ... | DO
1 | Elemento | Hidrógeno | Helio | Litio | ... | Oganesón
2 | Símbolo | H | He | Li | ... | Og
3 | Número atómico | 1 | 2 | 3 | ... | 118
4 | Masa atómica relativa | 1.008 | 4.0026 | 6.94 | ... | 294

=BUSCARH("Plomo"; $A$1:$DO$4; 2; 0) devuelve «Pb», el símbolo del plomo.

=BUSCARH("Oro"; $A$1:$DO$4; 3; 0) devuelve 79, el número atómico del oro.

=BUSCARH("Carbono"; $A$1:$DO$4; 4; 0) devuelve 12,011, la masa atómica relativa del carbono.

## BUSCARV

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Sintaxis

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Matriz es la referencia, la cual debe contener como mínimo la cantidad de columnas correspondiente al número pasado en el argumento Índice.

Índice es el número de la columna en la matriz que contiene el valor que se va a devolver. La primera columna tiene el número 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

Tratamiento de celdas vacías

#### Ejemplo

Desea escribir el número de un plato en el menú en la celda A1, de modo que el nombre del plato aparezca como texto en la celda vecina (B1). La asignación entre números y nombres está en la matriz D1:E100. D1 contiene 100, E1 contiene el nombre Sopa de vegetales, y así sucesivamente para 100 elementos del menú. Los números en la columna D son ordenados de manera ascendente; por lo tanto, el parámetro opcional Orden no es necesario.

Digite la fórmula siguiente en B1:

=BUSCARV(A1;D1:E100;2)

Al introducir un número en A1, en B1 aparece rápidamente el texto contenido en la segunda columna de la referencia D1:E100. Si se introduce un número inexistente, el texto que aparece es el correspondiente al número inferior más cercano. A fin de que esto no ocurra, hay que introducir un último parámetro FALSO en la fórmula de forma que en caso de introducir un número inexistente la función produzca como resultado un mensaje de error.

## COINCIDIR

Devuelve la posición relativa de un elemento de una matriz que coincide con el valor especificado. La función devuelve, en forma de número, la posición del valor encontrado en buscar_matriz.

#### Sintaxis

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

BuscarMatriz es la referencia buscada. Una matriz de búsqueda puede ser una sola fila o columna, o parte de una sola fila o columna.

Tipo puede tomar los valores 1, 0 o -1. Si Tipo = 1 o si falta este parámetro opcional, se asume que la primera columna de la matriz de búsqueda se ordena en orden ascendente. Si Tipo = -1, se asume que la columna se ordena en orden descendente. Esto se corresponde con la misma función en Microsoft Excel.

Si el Tipo es = 0, solo se encuentran resultados exactos. Si el criterio de búsqueda es encontrado más de una vez, la función devuelve el índice del primer valor encontrado. Solo si el Tipo es = 0 puedes buscar expresiones regulares (si están activadas en las opciones de cálculo) o comodines (si están activados en las opciones de cálculo).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Ejemplo

=COINCIDIR(200;D1:D100) busca el área D1:D100, que se ordena por la columna D, para el valor 200. Tan pronto como se alcanza este valor, el devuelve el número de la fila en que se encontró. Si se encuentra un valor mayor durante la búsqueda en la columna, se devuelve el número de la fila anterior.

## COLUMNA

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

#### Sintaxis

COLUMNA([Referencia])

Referencia es la referencia a una celda o un área de celdas cuyo número de columnas se va a buscar.

Si se omite la referencia, se calcula el número de columna de la celda en la que se introduce la fórmula. LibreOffice Calc establece automáticamente la referencia a la celda actual.

#### Ejemplo

=COLUMNA(A1) es igual a 1. La columna A es la primera de la tabla.

=COLUMNA(C3:E3) es igual a 3. La columna C es la tercera de la tabla.

=COLUMNA(D3:G10) devuelve 4 porque la columna D es la cuarta columna de la tabla y la función COLUMNA no se utiliza como una fórmula matricial. En este caso, el primer valor de la matriz se utiliza siempre como el resultado.

{=COLUMNA(B2:B7)} y =COLUMNA(B2:B7) devuelven 2 porque la referencia solo contiene la columna B como la primera columna de la tabla. Debido a que las áreas de una sola columna solo tienen un número de columna, no hay ninguna diferencia si la fórmula se utiliza como fórmula matricial o no.

=COLUMNA() devuelve 3 si la fórmula se especificó en la columna C.

{=COLUMNA(Conejo)} devuelve la matriz de una fila (3, 4) si "Conejo" es el área con nombre (C1:D3).

## COLUMNAS

Devuelve el número de columnas en la referencia especificada.

#### Sintaxis

COLUMNAS(Matriz)

Matriz es la referencia a un intervalo de celdas cuyo número total de columnas se va a buscar. El argumento también puede ser una única celda.

#### Ejemplo

=COLUMNAS(B5) devuelve 1 porque una celda contiene solamente una columna.

=COLUMNAS(A1:C5) es igual a 3. La referencia incluye tres columnas.

=COLUMNAS(Conejo) devuelve 2 si Conejo es el área con nombre (C1:D3).

## DDE

Devuelve el resultado de un enlace basado en DDE. Si el contenido del área o sección enlazada se modifica, el valor devuelto también cambiará. Para ver los enlaces actualizados se debe volver a cargar la hoja de cálculo o elegir Editar ▸ Enlaces. No se permite definir enlaces entre plataformas distintas, por ejemplo enlazar desde una instalación de LibreOffice en una máquina con Windows un documento creado en una máquina con Linux.

#### Sintaxis

DDE("Servidor"; "Archivo"; "Intervalo" [; Modo])

Servidor es el nombre de una aplicación de servidor. Las aplicaciones de LibreOffice tienen el nombre en servidor «soffice».

Archivo es el nombre completo de archivo, incluida la especificación de la ruta.

Intervalo es el área que contiene los datos que se van a evaluar.

Modo es un parámetro opcional que controla el método por el que el servidor DDE convierte sus datos en números.

Modo | Efecto
0 u omitido | Formato numérico procedente del estilo de celda «Predeterminado»
1 | Los datos se interpretan siempre con el formato predeterminado para inglés de EE.UU.
2 | Los datos se aceptan como texto; no se transforman en números

#### Ejemplo

=DDE("soffice";"c:\office\document\datos1.ods";"hoja1.A1") lee el contenido de la celda A1 de la hoja1 del libro de LibreOffice Calc «datos1.ods».

=DDE("soffice";"c:\office\document\máxima.odt";"Máxima del día") devuelve una máxima en la celda que contiene la fórmula. Primero, debe introducir un renglón en el documento «máxima.odt» que contenga el texto de la máxima y definirlo como el primer renglón de una sección que se llame Máxima del día (en LibreOffice Writer vaya a Insertar ▸ Sección). Si se modifica la máxima (y se guarda) en el documento de LibreOffice Writer, la máxima se actualiza en todas las celdas de LibreOffice Calc en las que se defina este enlace DDE.

## DESREF

Devuelve el valor de una celda desplazada una determinada cantidad de filas y columnas de un punto de referencia concreto.

This function is always recalculated whenever a recalculation occurs.

#### Sintaxis

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Referencia es la referencia desde la que la función busca una nueva referencia.

Filas es el número de filas en que se corrigió la referencia hacia arriba (valor negativo) o hacia abajo. Se usa 0 para permanecer en la misma fila.

Columnas es el número de columnas por el cual se corrigió la referencia hacia la izquierda (valor negativo) o la derecha. Utilice 0 para quedarse en la misma columna

Altura (opcional) es la altura vertical de un área que comienza en la nueva posición de referencia.

Anchura (opcional) es la anchura horizontal de un área que comienza en la posición de referencia nueva.

Los argumentos Filas y Columnas no deben resultar en una fila o columna inicial que dé cero o un valor negativo.

Argumentos Filas y Columnas no debe llevar a cero o un comienzo negativo de fila o columna.

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

#### Ejemplo

=DESREF(A1;2;2) devuelve el valor en la celda C3 (A1 movida por dos filas y dos columnas hacia abajo). Si C3 contiene el valor 100, esta función devuelve el valor 100.

=DESREF(B2:C3;1;1) devuelve una referencia a B2:C3 movida abajo 1 fila y una columna a la derecha (C3:D4).

=DESREF(B2:C3;-1;-1) devuelve una referencia a B2:C3 movida arriba 1 fila y una columna a la izquierda (A1:B2).

=DESREF(B2:C3;0;0;3;4) devuelve una referencia a B2:C3 con cambio de tamaño a 3 filas y 4 columnas (B2:E4).

=DESREF(B2:C3;1;0;3;4) devuelve una referencia a B2:C3 movida abajo una fila y con cambio de tamaño a 3 filas y 4 columnas (B3:E5).

=SUMA(DESREF(A1;2;2;5;6)) determina el total del área que comienza en la celda C3 y tiene una altura de 5 filas y una anchura de 6 columnas (área=C3:H7).

Si se especifican Anchura o Altura, la función DESREF devuelve una referencia a un intervalo de celdas. Si Referencia es una referencia a una única celda y se omiten tanto Anchura como Altura, se devuelve una referencia a una única celda.

## DIRECCION

Devuelve una dirección de celda (referencia) en forma de texto, según los números de fila y columna especificados. Se puede determinar si la dirección se interpreta como dirección absoluta (por ejemplo, $A$1), relativa (por ejemplo, A1) o mixta (A$1 o $A1). También se puede especificar el nombre de la hoja.

Por razones de interoperatividad, las funciones DIRECCION e INDIRECTO admiten un parámetro opcional para indicar si se debe utilizar la notación de dirección R1C1 en vez de la notación A1 habitual.

En DIRECCION, el parámetro se inserta como cuarto parámetro, desplazando el parámetro opcional del nombre de la hoja a la quinta posición.

En INDIRECTO, el parámetro se añade como el segundo parámetro.

En ambas funciones, si se inserta el argumento con el valor 0, se utiliza la notación R1C1. Si no se da el argumento o tiene un valor que no sea el 0, entonces se usa la notación A1.

En el caso de la notación R1C1, DIRECCION devuelve cadenas de dirección utilizando el signo de exclamación «!» como separador de los nombres de las hojas; INDIRECTO espera este signo. Ambas funciones aún utilizan el punto «.» como separador de nombres de hojas cuando se emplea la notación A1.

Al abrir documentos con el formato ODF 1.0/1.1, las funciones de DIRECCION que muestran un nombre de hoja como el cuarto parámetro trasladarán este nombre de hoja para convertirlo en un quinto parámetro. Se insertará un cuarto parámetro nuevo con el valor de 1.

Cuando se almacena un documento en formato ODF 1.0/1.1, si la función DIRECCION tiene un cuarto parámetro, este parámetro se eliminará.

No guarde el libro en el formato antiguo ODF 1.0/1.1 si se ha utilizado el cuarto parámetro de la función DIRECCION con un valor de 0.

La función INDIRECTO se guarda sin conversión al formato ODF 1.0/1.1. Si está presente el segundo parámetro, una versión antigua de Calc devolverá un error para esa función.

#### Sintaxis

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Fila representa el número de fila de la referencia de celda.

Columna representa el número de columna de la referencia de la celda (el número, no la letra).

Abs determina el tipo de referencia:

1: absoluto ($A$1)

2: Fila absoluta; Columna relativa (A$1)

3: fila (relativa); columna (absoluta) ($A1)

4: Relativa (A1)

A1 (opcional): si se define en 0, se utiliza la notación R1C1. Si falta este parámetro o se define en otro valor distinto de 0, se utiliza la notación A1.

Hoja representa el nombre de la hoja. Debe ir entre comillas dobles.

### Ejemplo:

=DIRECCION(1;1;2;;"Hoja2") devuelve lo siguiente: Hoja2.A$1

Si la fórmula anterior está en la celda B2 de la hoja actual, y la celda A1 de la hoja 2 contiene el valor -6, puede hacer referencia indirectamente a la celda de referencia utilizando una función en B2 introduciendo =ABS(INDIRECTO(B2)). El resultado es el valor absoluto de la referencia de celda especificada en B2, que en este caso es 6.

## ELEGIR

Utiliza un índice para producir un valor a partir de una lista formada por hasta 30 valores.

#### Sintaxis

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Índice es una referencia o número entre 1 y 30 que indica el valor que se va a tomar de la lista.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

#### Ejemplo

=ELEGIR(A1;B1;B2;B3;"Hoy";"Ayer";"Mañana"), por ejemplo, devuelve el contenido de la celda B2 para A1 = 2; para A1 = 4, la función devuelve el texto «Hoy».

## ESTILO

Aplica un estilo a la celda que contiene la fórmula. Después de un tiempo determinado, se puede aplicar otro estilo. Esta función siempre devuelve el valor 0, que permite agregarlo a otra función sin cambiar el valor. Junto con la función ACTUAL, puede aplicar un color a una celda en función de su valor. Por ejemplo: =… + ESTILO(SI(ACTUAL()>3;"rojo";"verde")) aplica el estilo «rojo» a la celda si el valor es mayor que 3; si es menor, se aplica el estilo «verde». Ambos formatos de celda, «rojo» y «verde», deben haberse definido previamente.

#### Sintaxis

ESTILO("Estilo" [; Tiempo [; "Estilo2"]])

Estilo es el nombre del estilo de celda asignado a la celda. Los nombres de estilo deben escribirse entre comillas.

Tiempo es un intervalo de tiempo opcional en segundos. Si falta este parámetro, el estilo no se cambiará trascurrida una cantidad determinada de tiempo.

Estilo2 es el nombre opcional de un estilo de celda asignado a la celda tras un determinado intervalo de tiempo. Si falta este parámetro, se utiliza «Predeterminado».

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

#### Ejemplo

=ESTILO("Invisible";60;"Predeterminado") asigna el formato transparente a la celda durante 60 segundos después de volver a calcular o cargar el documento, a continuación, se asigna el formato Predeterminado. Los dos formatos de celda deben haberse definido previamente.

Dado que ESTILO() devuelve un valor numérico de cero, este valor de retorno se anexa al texto. Es posible evitar este comportamiento al utilizar T(), como en el ejemplo siguiente:

="Texto"&T(ESTILO("miEstilo"))

Consulte también ACTUAL() para otro ejemplo.

## FILA

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

#### Sintaxis

FILA([Referencia])

Referencia es una celda, un área o el nombre de un área.

Si se omite la referencia, la función calcula el número de fila de la celda en la que se introduce la fórmula. LibreOffice Calc establece automáticamente la referencia a la celda actual.

#### Ejemplo

=FILA(B3) devuelve 3 porque la referencia hace mención a la tercera fila de la tabla.

{=FILA(D5:D8)} devuelve la matriz de una columna (5, 6, 7, 8) porque la referencia especificada contiene las filas 5 a 8.

=FILA(D5:D8) devuelve 5 porque la función FILA no se utiliza como fórmula matricial y solo se devuelve el número de la primera fila de la referencia.

{=FILA(A1:E1)} y =FILA(A1:E1) devuelven 1 porque la referencia solo contiene la fila 1 como la primera fila de la tabla. Debido a que las áreas de una sola fila solo tienen un número de fila, no hay ninguna diferencia si la fórmula se utiliza como fórmula matricial o no.

=FILA() devuelve 3 si la fórmula se especificó en la fila 3.

{=FILA(Conejo)} devuelve la matriz de una columna (1, 2, 3) si «Conejo» es el intervalo con nombre (C1:D3).

## FILAS

Devuelve el número de filas de una referencia o matriz.

#### Sintaxis

FILAS(Matriz)

Matriz es la referencia o área con nombre cuyo número total de filas se va a determinar.

#### Ejemplo

=Filas(B5) devuelve 1 porque una celda contiene solamente una fila.

=FILAS(A10:B12) devuelve 3.

=FILAS(Conejo) devuelve 3 si «Conejo» es el intervalo con nombre (C1:D3).

## HIPERVINCULO

Al pulsar en una celda que contenga la función HIPERVINCULO, se abre el hiperenlace.

Si utiliza el parámetro Texto de la celda opcional, la fórmula localiza el URL y muestra el texto o número.

Para abrir con el teclado una celda con hiperenlace, seleccione la celda, presione F2 para acceder al modo de edición, mueva el cursor delante del hiperenlace, presione Mayús + F10 y, a continuación, seleccione Abrir hiperenlace.

#### Sintaxis

HIPERVINCULO("URL" [; "Texto en la celda"])

URL especifica el destino del vínculo. El parámetro TextodeCelda opcional es el texto o un número que se muestra en la celda y que se devolverá como resultado. Si no se especifica el parámetro TextodeCelda, se muestra la dirección URL en el texto de la celda y se devolverá como resultado.

Se devuelve el número 0 para las celdas y los elementos de matriz vacíos.

#### Ejemplo

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HIPERVINCULO("http://www.";"Visite ") & "ejemplo.org" muestra el texto «Visite ejemplo.org» en la celda y ejecuta el hiperenlace http://www.ejemplo.org cuando se pulsa con el ratón.

=HIPERVINCULO("#Hoja1.A1";"Ir al principio") muestra el texto «Ir al principio» y salta a la celda Hoja1.A1 de este documento.

=HIPERVINCULO("file:///C:/writer.odt#Especificación";"Ir al marcador de Writer") muestra el texto «Ir al marcador de Writer», carga el documento de texto especificado y salta al marcador «Especificación».

=HIPERVINCULO("file:///C:/Documents/";"Abrir la carpeta Documentos") muestra el texto «Abrir la carpeta Documentos» y muestra el contenido de la carpeta utilizando el gestor de archivos estándar del sistema operativo.

## HOJAS

Determina el número de hojas de una referencia. Si no especifica ningún parámetro, devuelve el número de hojas del documento actual.

#### Sintaxis

HOJAS([Referencia])

Referencia es la referencia a una hoja o área. Este parámetro es opcional.

#### Ejemplo

=HOJAS(Hoja1.A1:Hoja3.G12) devuelve 3 si Hoja1, Hoja2 y Hoja3 existen en la secuencia indicada.

## IMPORTARDATOSDINAMICOS

La función IMPORTARDATOSDINAMICOS devuelve un valor de resultado de una tabla dinámica. El valor se señala mediante los nombres del campo y de los elementos, de modo que siga siendo válido si cambia la disposición de la tabla dinámica.

#### Sintaxis

Se puede usar dos diferentes definiciones en la sintaxis:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

o

IMPORTARDATOSDINAMICOS(TablaDinámica; Limitantes)

Se asume la segunda sintaxis si se proporcionan exactamente dos parámetros, el primero de los cuales es una celda o una referencia a un intervalo de celdas. En el resto de los casos se asume la primera sintaxis. El Asistente de funciones muestra la primera sintaxis.

### Primera sintaxis

CampoDestino es una cadena que selecciona uno de los campos de datos de la tabla dinámica. La cadena puede ser el nombre de la columna de origen o el nombre del campo de datos como se muestra en la tabla (como «Suma - Ventas»).

tabla dinámica es una referencia a una celda o intervalo de celdas que se ubica dentro de una tabla dinámica o contiene una tabla dinámica. Si el intervalo de celdas contiene varias tablas dinámicas, se utiliza la última tabla que se creó.

Si no hay pares ha dado Campos n / Elementos n, el gran total no devuelve nada. De cualquier forma, cada par agrega una constante que el resultado debe ser satisfecho. Campo n es el nombre del campo de la tabla de Piloto de datos. Elemento n es el nombre del elemento del campo.

Si la tabla dinámica solamente contiene un solo valor de resultado que cumpla con todas las limitantes, o un resultado de subtotal que resume todos los valores coincidentes, se devuelve ese resultado. Si no hay un resultado coincidente, o varios que carezcan de un subtotal, se devuelve un error. Estas condiciones aplican a los resultados que se incluyen en la tabla dinámica.

Si el origen de datos contiene entradas que están ocultas por la configuración de la tabla dinámica, ellas se ignoran. No importa el orden de los pares Campo/Elemento. Los nombres de los campos y de los elementos no distinguen entre mayúsculas y minúsculas.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Los valores de subtotal de la tabla dinámica se utilizan solo si estos usan la función «auto» (excepto cuando se especifican en la restricción; en este caso, consulte Segunda sintaxis más abajo).

### Segunda sintaxis

tabla dinámica tiene el mismo significado que en la primera sintaxis.

Limitantes es una lista separada por espacios. Las entradas se pueden poner entre comillas (comillas simples). Toda la cadena se debe poner entre comillas (comillas dobles), a menos que haga referencia a la cadena desde otra celda.

Una de las entradas puede ser el nombre del campo de datos. El nombre del campo de datos puede omitirse si la tabla dinámica contiene solamente un campo de datos, pero de lo contrario debe estar presente.

Cada una de las otras entradas indica una restricción en la forma Campo[Elemento] (con los caracteres literales [ y ]), o únicamente Elemento si el nombre del elemento es único en todos los campos que se utilicen para la tabla dinámica.

Un nombre de función puede se añadido en la forma Campo[Elemento;Función], que harán que el contraste para que coincida con los valores subtotales que solamente usa esa función. Los posibles nombres de las funciones son Suma, Contar, Promedio, Max, Min, Producto, Contar(Sólo números), DesvEst(Muestra), DesvEst(Población), Var(Muestra), y VarP(Población), distingue entre mayúsculas y minúsculas.

## INDICE

INDICE devuelve un subintervalo, especificado por el número de línea y columna o un índice de intervalo opcional. En función del contexto, INDICE devolverá una referencia o un contenido.

#### Sintaxis

INDICE(Referencia [; Fila [; Columna [; Intervalo]]])

Referencia es una referencia, ingresada directamente o mediante un nombre de intervalo. Si la referencia consta de varios intervalos, la referencia o el nombre de intervalo debe ir entre paréntesis.

Fila (opcional) representa el índice de fila del intervalo de referencia, para la cual devolver un valor. En caso de cero (ninguna fila específica) se devuelven todas las filas referenciadas.

Columna (opcional) representa el índice de columna del intervalo de referencia, para la cual devolver un valor. En caso de cero (ninguna columna específica) se devuelven todas las columnas referenciadas.

Intervalo (opcional) representa el índice del subintervalo si hace referencia a un intervalo múltiple.

#### Ejemplo

=INDICE(Precios;4;1) devuelve el valor de la fila 4 y la columna 1 del intervalo de base de datos definido como Precios en Datos ▸ Definir intervalo.

=ÍNDICE(SumaX;4;1) devuelve el valor del intervalo SumaX entre la fila 4 y la columna 1 como se define en Hoja ▸ Intervalos y expresiones con nombre ▸Definir.

=INDICE(A1:B6;1) devuelve una referencia a la primera fila de A1:B6.

=INDICE(A1:B6;0;1) devuelve una referencia a la primera columna de A1:B6.

=INDICE((multi);4;1) indica el valor contenido en la fila 4 y columna 1 del intervalo (múltiple) al cual se asignó el nombre multi a través de Insertar ▸ Intervalos y expresiones con nombre ▸ Definir. El intervalo múltiple puede consistir de varios intervalos rectangulares, cada uno de los cuales con una fila 4 y columna 1. Después, si desea acceder al segundo bloque de este intervalo múltiple, ingrese el número 2 como parámetro intervalo.

=INDICE(A1:B6;1;1) indica el valor en la parte superior izquierda del intervalo A1:B6.

=INDICE((multi);0;0;2) devuelve una referencia al segundo intervalo del intervalo múltiple.

## INDIRECTO

Devuelve la referencia especificada por una cadena de texto. Esta función también se puede utilizar para calcular el área de la cadena correspondiente.

This function is always recalculated whenever a recalculation occurs.

Por razones de interoperatividad, las funciones DIRECCION e INDIRECTO admiten un parámetro opcional para indicar si se debe utilizar la notación de dirección R1C1 en vez de la notación A1 habitual.

En DIRECCION, el parámetro se inserta como cuarto parámetro, desplazando el parámetro opcional del nombre de la hoja a la quinta posición.

En INDIRECTO, el parámetro se añade como el segundo parámetro.

En ambas funciones, si se inserta el argumento con el valor 0, se utiliza la notación R1C1. Si no se da el argumento o tiene un valor que no sea el 0, entonces se usa la notación A1.

En el caso de la notación R1C1, DIRECCION devuelve cadenas de dirección utilizando el signo de exclamación «!» como separador de los nombres de las hojas; INDIRECTO espera este signo. Ambas funciones aún utilizan el punto «.» como separador de nombres de hojas cuando se emplea la notación A1.

Al abrir documentos con el formato ODF 1.0/1.1, las funciones de DIRECCION que muestran un nombre de hoja como el cuarto parámetro trasladarán este nombre de hoja para convertirlo en un quinto parámetro. Se insertará un cuarto parámetro nuevo con el valor de 1.

Cuando se almacena un documento en formato ODF 1.0/1.1, si la función DIRECCION tiene un cuarto parámetro, este parámetro se eliminará.

No guarde el libro en el formato antiguo ODF 1.0/1.1 si se ha utilizado el cuarto parámetro de la función DIRECCION con un valor de 0.

La función INDIRECTO se guarda sin conversión al formato ODF 1.0/1.1. Si está presente el segundo parámetro, una versión antigua de Calc devolverá un error para esa función.

#### Sintaxis

INDIRECTO(Ref [; A1])

Ref representa una referencia a una celda o a un área (con formato de texto) para la que se devuelve el contenido.

A1 (opcional): si se define en 0, se utiliza la notación R1C1. Si falta este parámetro o se define en otro valor distinto de 0, se utiliza la notación A1.

Si abre un libro de Excel que utiliza direcciones indirectas calculadas a partir de funciones de cadena, las direcciones de la hoja no se traducirán automáticamente. Por ejemplo, la dirección de Excel en INDIRECTO("[nombredearchivo]nombredehoja!"&B1) no se convierte en la dirección de Calc en INDIRECTO("nombredearchivo#nombredehoja."&B1).

#### Ejemplo

=INDIRECTA(A1) es igual a 100 si A1 contiene C108 como referencia y la celda C108 contiene un valor de 100.

=SUMA(INDIRECTA("a1:" & DIRECCION(1;3))) suma las celdas en el área entre A1 y la celda con la dirección definida por la fila 1 y columna 3, o, en otras palabras, se suma el intervalo A1:C1.

## SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

#### Sintaxis

HOJA([Referencia])

Referencia es opcional; es la referencia a una celda, un área o una cadena de nombre de hoja.

#### Ejemplo

=HOJA(Hoja2.A1) devuelve 2 si la Hoja2 es la segunda hoja en el documento de hoja de cálculo.

=HOJA("Hoja3") devuelve 3 si la Hoja3 es la tercera hoja en el documento de hoja de cálculo.

## TIPO.DE.ERROR.OOO

Devuelve el número correspondiente a un valor de error que se produce en una celda distinta. Con la ayuda de este número, puede generar un texto de mensaje de error.

Si se produce un error, la función devuelve un valor lógico o numérico.

En la barra de estado se muestra el código de error predefinido de LibreOffice si pulsa en la celda que contiene el error.

#### Sintaxis

TIPO.DE.ERROR.OOO(Referencia)

Referencia contiene la dirección de la celda en la que se produce el error.

#### Ejemplo

Si la celda A1 muestra el Error:518, la función =TIPO.DE.ERROR.OOO(A1) devuelve el número 518.

Temas relacionados

Funciones por categoría