Contenido
Índice 🔎︎

# Funciones de texto

Esta sección contiene descripciones de las funciones de Texto.

Para acceder a esta orden…

Insertar ▸ Función ▸ categoría Texto

## Utilizar comillas dactilográficas dobles (") en fórmulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

## ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

## ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

## JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

## EXP.REG

Encuentra y extrae, u opcionalmente reemplaza, texto, con ayuda de expresiones regulares.

## ROMANO

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

## VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

### WEBSERVICE

Obtiene contenido web a partir de un URI.

### FILTERXML

Aplica una expresión XPath en un documento XML.

### ENCODEURL

Devuelve una cadena codificada como URL.

## BASE

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

#### Sintaxis

BASE(Number; Radix [; MinimumLength])

Número es el número entero positivo se debe convertir.

Radix indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.

LongitudMínima (opcional) determina la longitud mínima de la secuencia de caracteres que se ha creado. Si el texto es más corto que la longitud mínima indicada, se agregan ceros a la izquierda de la cadena.

#### Ejemplo

=BASE(17;10;4) devuelve 0017 en el sistema decimal.

=BASE(17;2) devuelve 10001 en el sistema binario.

=BASE(255;16;4) devuelve 00FF en el sistema hexadecimal.

## BUSCAR

Devuelve la posición de un segmento de texto dentro de una cadena de caracteres. Opcionalmente puede fijar el inicio de la búsqueda. El texto buscado puede ser un número o una cadena de caracteres. La búsqueda no distingue mayúsculas de minúsculas. Si no se encuentra el texto, se devuelve el error 519 (#VALOR).

La búsqueda admite los caracteres comodín y las expresiones regulares. Cuando se activan estas últimas, podrá introducir «des.*», por ejemplo, para encontrar la primera ocurrencia del prefijo «des-» seguida por cualesquier caracteres. Si desea buscar un texto que es en sí mismo una expresión regular, puede bien anteponer a todos los caracteres una «\», o bien rodear el texto con \Q...\E. Puede activar o desactivar el procesamiento automático de los comodines y las expresiones regulares si se dirige a LibreOffice ▸ Preferencias Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

#### Sintaxis

SEARCH("FindText"; "Text" [; Position])

Encontrar_Texto es el texto que se debe buscar.

Texto es el texto donde se realiza la búsqueda.

Posición (opcional) es la posición en el texto donde se iniciará la búsqueda.

#### Ejemplo

=BUSCAR(54;998877665544) devuelve 10.

## CARACTER

Convierte un número en un carácter según la tabla de códigos actual. El número puede ser un entero de dos o de tres dígitos.

Los códigos mayores que 127 pueden depender de la asignación de caracteres del sistema (por ejemplo, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) y, por ello, pueden no ser portátiles.

#### Sintaxis

CARACTER(Número)

Número es un número entre 1 y 255 que representa el valor de código del carácter.

#### Ejemplo

=CARACTER(100) devuelve el carácter «d».

="abc" & CARACTER(10) & "def" inserta un carácter de salto de renglón en la cadena.

## CODIGO

Devuelve un código numérico para el primer carácter de una cadena de texto.

#### Sintaxis

CODIGO("Texto")

Texto es el texto para el que se buscará el código del primer carácter.

Los códigos mayores que 127 pueden depender de la asignación de caracteres del sistema (por ejemplo, iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) y, por ello, pueden no ser portátiles.

#### Ejemplo

=CODIGO("Jerónimo") devuelve 74, =CODIGO("jeroglífico") devuelve 106.

El código utilizado en este caso no es el código ASCII, sino el código de la tabla de códigos actual.

## CONCATENAR

Combina varias cadenas de caracteres en una sola.

#### Sintaxis

CONCATENAR(String 1 [; String 2 [; … [; String 255]]])

String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.

#### Ejemplo

=CONCATENAR("Buenos ";"días, ";"Sra. ";"López") devuelve «Buenos días, Sra. López».

## DECIMAL

Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

Si la raíz es 16 se despreciarán los caracteres x, X, 0x o 0X que precedan al texto, así como los caracteres h o H agregados al final. Si la raíz es 2 se despreciarán los caracteres b o B agregados al final. Otros caracteres que no pertenezcan al sistema numérico provocarán un error.

#### Sintaxis

DECIMAL("Texto"; Base)

Texto es el texto que se debe convertir. Para diferenciar entre un número hexadecimal, por ejemplo A1 y la referencia a la celda A1, debe escribir el número entre comillas; por ejemplo, "A1" o "FACE".

Base indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.

#### Ejemplo

=DECIMAL("17";10) devuelve 17.

=DECIMAL("FACE";16) devuelve 64206.

=DECIMAL("0101";2) devuelve 5.

## DERECHA

Devuelve el último carácter o los últimos caracteres de un texto.

#### Sintaxis

RIGHT("Text" [; Number])

Texto es el texto para el que se va a determinar la parte derecha.

Número (opcional) es la cantidad de caracteres de la parte derecha del texto. Si no se define este parámetro, se devuelve un carácter.

#### Ejemplo

=DERECHA("Sol";2) devuelve «ol».

## DERECHAB

Devuelve el último carácter o caracteres de un texto en DBCS (conjunto de caracteres de bytes dobles).

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

RIGHTB("Text" [; Number_bytes])

Texto es el texto cuya parte derecha se determinará.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

#### Ejemplo

IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).

DERECHAB("中国";2) devuelve «国» (2 bytes constituyen un carácter DBCS completo).

DERECHAB("中国";3) devuelve « 国» (3 bytes constituyen un carácter DBCS y una mitad, se devuelve un espacio por la primera mitad).

DERECHAB("中国";4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).

DERECHAB("capuchino";5) devuelve «chino» (5 caracteres no DBCS, cada uno con la medida de 1 byte).

## ENCONTRAR

Devuelve la posición de una cadena de texto dentro de otra cadena. También puede definirse el punto de inicio de la búsqueda. El término buscado puede ser un número o una cadena de caracteres. La búsqueda distingue entre mayúsculas y minúsculas.

#### Sintaxis

FIND("FindText"; "Text" [; Position])

QuéEncontrar hace referencia al texto que se debe buscar.

Texto es el texto donde se realiza la búsqueda.

Posición (opcional) es la posición en el texto donde se iniciará la búsqueda.

#### Ejemplo

=BUSCAR(76;998877665544) devuelve 6.

## ESPACIOS

Elimina los espacios de una cadena de caracteres y deja un solo espacio entre palabras.

#### Sintaxis

ESPACIOS("Texto")

Text se refiere al texto cuyos espacios se han de eliminar.

#### Ejemplo

=ESPACIOS(" hola, mundo ") devuelve «hola, mundo» sin los espacios inicial y final y con un único espacio entre las palabras.

## EXTRAE

Devuelve una cadena de texto de un texto. Los parámetros especifican la posición inicial y el número de caracteres.

#### Sintaxis

EXTRAE("Texto"; Comienzo; Número)

Texto es el texto que contiene los caracteres que se van a extraer.

Inicio es la posición del primer carácter del texto que se va a extraer.

Número especifica el número de caracteres en la parte del texto.

#### Ejemplo

=EXTRAE("oficina";2;2) devuelve «fi».

## EXTRAEB

Devuelve una cadena de texto en DBCS. Los parámetros especifican la posición inicial y la cantidad de caracteres.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

EXTRAEB("Texto"; Comienzo; Número_de_bytes)

Texto es el texto que contiene los caracteres que se van a extraer.

Inicio es la posición del primer carácter del texto que se extraerá.

Número_de_bytes especifica la cantidad de caracteres que EXTRAEB extraerá del texto, en bytes.

#### Ejemplo

=EXTRAEB("中国";1;0) devuelve «» (0 bytes siempre es una cadena vacía).

=EXTRAEB("中国";1;1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, el resultado es un carácter de espacio).

=EXTRAEB("中国";1;2) devuelve «中» (2 bytes constituyen un carácter DBCS completo).

=EXTRAEB("中国";1;3) devuelve «中 » (3 bytes constituyen un carácter DBCS y medio; el último byte da como resultado un carácter de espacio).

=EXTRAEB("中国";1;4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).

=EXTRAEB("中国";2;1) devuelve « » (la posición de byte 2 no está al principio de un carácter en una cadena DBCS; se devuelve 1 carácter de espacio).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

## FIJO

Returns a number as text with a specified number of decimal places and optional thousands separators.

#### Sintaxis

FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])

Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.

Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.

NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

#### Ejemplo

=FIJO(1234567,89;3) devuelve 1.234.567,890 como cadena de texto.

=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.

=FIXED(12345.6789;-2) returns 12,300 as a text string.

=FIJO(12134567.89;-3;1) devuelve 12135000 como una cadena de texto.

=FIJO(12345.789;3/4) devuelve 12,346 como una cadena de texto.

=FIJO(12345.789;8/5) devuelve 12.345,8 como cadena de texto.

## IGUAL

Compara dos cadenas de texto y devuelve VERDADERO si son iguales. Esta función distingue entre mayúsculas y minúsculas.

#### Sintaxis

IGUAL("Texto1"; "Texto2")

Texto1 hace referencia al primer texto que se comparará.

Texto2 es el segundo texto que se va comparar.

#### Ejemplo

=IGUAL("microsystems";"Microsystems") devuelve FALSO.

## IZQUIERDA

Devuelve el primer carácter o los primeros caracteres de un texto.

#### Sintaxis

IZQUIERDA("Texto" [; Número])

Texto es la cadena de texto cuyas palabras parciales iniciales se determinarán.

Número (opcional) especifica el número de caracteres para el texto inicial. Si no se ha definido este parámetro, se devuelve un carácter.

#### Ejemplo

=IZQUIERDA("salida";3) devuelve «sal».

## IZQUIERDAB

Devuelve los primeros caracteres de un texto en DBCS.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

IZQUIERDAB("Texto" [; Número_bytes])

Texto es la cadena de texto cuyas palabras parciales iniciales se determinarán.

Número_de_bytes (opcional) especifica la cantidad de caracteres que extraerá IZQUIERDAB, medido en bytes. Si no se define este parámetro, se devolverá un carácter.

#### Ejemplo

=IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y en su lugar se devuelve un carácter de espacio).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

## LARGO

Calcula la longitud de una cadena, incluidos los espacios.

#### Sintaxis

LARGO("Texto")

Texto es el texto cuya longitud debe determinarse.

#### Ejemplo

=LARGO("Buenas tardes") devuelve 13.

=LARGO(12345.67) devuelve 8.

## LARGOB

Para los idiomas que utilizan un conjunto de caracteres de bytes dobles (DBCS), devuelve la cantidad de bytes usada para representar los caracteres de una cadena de texto.

Esta función está disponible desde la versión 4.2 de LibreOffice.

#### Sintaxis

LARGOB("Texto")

Texto es el texto cuya longitud debe determinarse.

#### Ejemplo

LARGOB("中") devuelve 2 (1 carácter DBCS, equivalente a 2 bytes).

LARGOB("中国") devuelve 4 (2 caracteres DBCS, cada uno equivalente a 2 bytes).

LARGOB("Caifanes") devuelve 8 (8 caracteres no DBCS, cada uno con la medida de 1 byte).

=LARGOB("Buenas tardes") devuelve 13.

=LARGOB(12345.67) devuelve 8.

## LIMPIAR

Elimina de la cadena todos los caracteres que no se pueden imprimir.

#### Sintaxis

LIMPIAR("Texto")

Texto hace referencia al texto del que se eliminarán todos los caracteres no imprimibles.

#### Ejemplo

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.

## MAYUSC

Pasa la cadena especificada en el campo de texto a mayúsculas.

#### Sintaxis

MAYUSC("Texto")

Texto hace referencia a las letras en minúsculas que desea convertir a mayúsculas.

#### Ejemplo

=MAYUSC("Buenos días") devuelve BUENOS DÍAS.

## MINUSC

Convierte todas las letras mayúsculas de una cadena de texto en minúsculas.

#### Sintaxis

MINUSC("Texto")

Texto hace referencia al texto que se debe convertir.

#### Ejemplo

=MINUSC("Sun";2) devuelve sun.

## MONEDA

Convierte un número en una cantidad en el formato monetario, redondeada a la cantidad de decimales que especifique. En el campo Valor digite el número que quiere convertir en moneda. Opcionalmente, puede especificar el número de decimales en el campo Decimales. Si no se especifica ningún valor, todos los números en el formato monetario se mostrarán con dos decimales.

Debe establecer el formato de la divisa en la configuración del sistema.

#### Sintaxis

DOLLAR(Value [; Decimals])

Valor es un número, una referencia a una celda que contiene un número o una fórmula que da como resultado un número.

Decimales es el número opcional de posiciones decimales.

#### Ejemplo

=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ￥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.

=MONEDA(367,456;2) devuelve $367,46. Utilice el separador decimal que se corresponda con la configuración regional actual.

## NOMPROPIO

En el caso de una cadena de texto, convierte en mayúscula la inicial de todas las palabras de la cadena.

#### Sintaxis

NOMPROPIO("Texto")

Texto hace referencia al texto que se debe convertir.

#### Ejemplo

=NOMPROPIO("the document foundation") devuelve The Document Foundation.

## REEMPLAZAR

Sustituye parte de una cadena de texto con una cadena de texto distinta. Esta función se puede utilizar para sustituir caracteres y números (que se convierten automáticamente en texto). El resultado de la función siempre es un texto. Para proseguir con la operación de cálculo con un número reemplazado por texto, es preciso transformar el resultado de nuevo en número; para ello, se utiliza la función VALOR.

Si no desea que un texto que contenga números se interprete como número y se convierta en texto automáticamente deberá escribirlo entre comillas.

#### Sintaxis

REEMPLAZAR("Texto"; Posición; Longitud; "texto_nuevo")

Texto hace referencia al texto del que se sustituirá una parte.

Posición hace referencia a la posición del texto en la que comenzará la sustitución.

Longitud es el número de caracteres en Texto que se va a sustituir.

texto_nuevo hace referencia al texto que sustituye a Texto.

#### Ejemplo

=REEMPLAZAR("1234567";1;1;"444") devuelve "444234567". Un carácter en la posición 1 se sustituye por el texto_nuevo completo.

## REPETIR

Repite una cadena de caracteres el número de veces especificado.

#### Sintaxis

REPETIR("Texto"; Número)

Texto es el texto que se debe repetir.

Número es el número de repeticiones.

#### Ejemplo

=REPETIR("Buenos días") devuelve Buenos díasBuenos días.

Refer to the REPT wiki page for more details about this function.

## SUSTITUIR

Reemplaza un fragmento de texto por otro nuevo dentro de una cadena de caracteres.

#### Sintaxis

SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])

Texto es el texto en el que se van a intercambiar los segmentos de texto.

Buscar_texto es el segmento de texto que se va a sustituir (un número de veces).

texto_nuevo es el texto que va a sustituir al segmento de texto.

Aparición (opcional) indica la aparición del texto buscado que se reemplazará. Si no se especifica este parámetro, el texto de la búsqueda se reemplazará en todas partes.

#### Ejemplo

=SUSTITUIR("123123123";"3";"abc") devuelve 12abc12abc12abc.

=SUSTITUIR("123123123";"3";"abc";2) devuelve 12312abc123.

## T

Esta función devuelve el texto de destino, o una cadena de texto vacía si el destino no es texto.

#### Sintaxis

T(Valor)

Si Valuor es una cadena de texto o se refiere a una cadena de texto. T devolverá esa cadena; de lo contrario devolvera una cadena en vacia.

#### Ejemplo

=T(12345) devuelve una cadena vacía.

=T("12345") devuelve la cadena 12345.

## TEXTO

Converts a value into text according to a given format.

#### Sintaxis

TEXT(Value; Format)

Value is the value (numerical or textual) to be converted.

Formato es el texto que define el formato. Use separadores de decimales y millares de acuerdo con el idioma definido en el formato de celda.

#### Ejemplo

=TEXTO(12,34567;"###,##") devuelve el texto 12,35.

=TEXTO(12,34567;"000,00") devuelve el texto 012,35.

=TEXT("xyz";"=== @ ===") returns the text === xyz ===

Consulte también Códigos de formato numérico: códigos de formato personalizados definidos por el usuario.

## TEXTOBAHT

Convierte un número en texto tailandés, incluso los nombres de monedas tailandeses.

#### Sintaxis

TEXTOBAHT(Número)

Número es cualquier número. "Baht" se agrega a la parte entera del número y "Satang" se agrega a la parte decimal del número.

#### Ejemplo

=TEXTOBAHT(12,65) devuelve una cadena de caracteres tailandeses que representan «Doce bahts y sesentaicinco satangs».

## UNICAR

Convierte un número de código en un carácter o letra Unicode.

#### Sintaxis

UNICAR(número)

#### Ejemplo

=UNICAR(169) da como resultado el carácter de derechos de autor, ©.

Consulte también la función UNICODE().

## UNICODE

Devuelve el código numérico del primer carácter Unicode de una cadena de texto.

#### Sintaxis

UNICODE("Texto")

#### Ejemplo

=UNICODE("©") devuelve el número Unicode 169 para el carácter de Copyright.

Consulte también la función UNICAR().

Temas relacionados

Funciones por categoría